home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do / DOCTOR.bas < prev    next >
BASIC Source File  |  1996-12-24  |  7KB  |  159 lines
  1. 10  REM  DOCTOR
  2. 20  GOSUB 90
  3. 30  GOSUB 160
  4. 40  GOSUB 250
  5. 50  GOSUB 410
  6. 60  GOSUB 910
  7. 70  GOSUB 970
  8. 80  GOTO 30
  9. 90  REM  INITIALIZATION
  10. 100 NM = 28
  11. 110 NU = 82
  12. 130  HOME : PRINT : PRINT 
  13. 140  PRINT "PLEASE STATE YOUR PROBLEM."
  14. 150  RETURN 
  15. 160  REM  INPUT
  16. 170  RESTORE 
  17. 180 X = 0
  18. 190  INPUT PA$
  19. 200  IF PA$ = ""  THEN  PRINT "DO YOU HAVE A PROBLEM?":X = 1: GOTO 240
  20. 210  IF PA$ = PR$  THEN  PRINT "PLEASE DON'T REPEAT YOURSELF!":X = 1: GOTO 240
  21. 220 PR$ = PA$
  22. 230 PA$ = " " + LEFT$(PA$, LEN(PA$) -1) +" "
  23. 240  RETURN 
  24. 250  REM  SWAP WORD
  25. 260  IF X = 1  THEN 400
  26. 270  FOR I = 1 TO NM/2
  27. 280  READ TE$,TN$
  28. 290  FOR PS = 1 TO  LEN(PA$) - LEN(TE$) +1
  29. 300  IF TE$ =  MID$ (PA$,PS, LEN(TE$))  THEN PA$ =  LEFT$(PA$,PS) +TN$ + MID$ (PA$,PS + LEN(TE$))
  30. 310  DATA  " MOM ", " MOTHER ", " DAD ", " FATHER "
  31. 320  DATA  " DREAMS ", " DREAM "
  32. 330  DATA  " I "," YOU@ "," YOU "," I "," ME "," YOU "
  33. 340  DATA  "MY","YOUR*"
  34. 350  DATA  " YOUR "," MY "," MYSELF "," YOURSELF* "
  35. 360  DATA   " YOURSELF "," MYSELF "
  36. 370  DATA " I'M "," YOU'RE* "," YOU'RE "," I'M "," AM "," ARE@ "
  37. 380  DATA  " WERE "," WAS "
  38. 390  NEXT PS,I
  39. 400  RETURN 
  40. 410  REM  KEYWORDS
  41. 420  REM  KEYWORDS.CHECKING
  42. 430  IF X = 1  THEN 900
  43. 440  FOR I = 1 TO NU
  44. 450  READ KE$,JU
  45. 460  FOR PS = 1 TO  LEN(PA$) - LEN(KE$) +1
  46. 470  IF KE$ < > MID$ (PA$,PS, LEN(KE$))  THEN 480
  47. 475 DR$ =  MID$ (PA$,PS + LEN(KE$)): IF DR$ < >""  THEN 500
  48. 476  PRINT DR$
  49. 477  GOTO 900
  50. 480  NEXT PS,I
  51. 490  GOTO 790
  52. 500  GOTO 900
  53. 510  DATA  "COMPUTER", 1, "MACHINE", 1
  54. 520  DATA  " NAME ",2,"ALIKE",3," LIKE ",3," SAME ",3
  55. 530  DATA  "YOU@ REMEMBER", 4, "DO I REMEMBER", 5, "YOU@ DREAMED",6
  56. 540  DATA  " DREAM ",7," IF ",8, "EVERYBODY", 9, "EVERYONE", 9
  57. 550  DATA   "NOBODY", 9, "NO ONE", 9,  "WAS YOU@", 10, "YOU@ WAS", 11   
  58. 560  DATA  "WAS I", 12, "YOUR* MOTHER", 13, "YOUR* FATHER", 13
  59. 570  DATA  "YOUR* SISTER", 13, "YOUR* BROTHER", 13, "YOUR* WIFE", 13
  60. 580  DATA  "YOUR* HUSBAND", 13, "YOUR* CHILDREN", 13, "YOUR*", 14
  61. 590  DATA   "ALWAYS", 15, "ARE I", 16, "ARE@ YOU@", 18," HOW ",25
  62. 600  DATA  "BECAUSE", 19, "CAN I", 20, "CAN YOU@", 21, "CERTAINLY", 22
  63. 610  DATA  "DEUTSCH", 23, "ESPANOL", 23, "FRANCAIS", 23, "HELLO", 24
  64. 620  DATA  "I REMIND YOU OF", 3, "I ARE", 26, "I'M", 26
  65. 630  DATA   "ITALIANO", 23, "MAYBE", 28," MY ",29," NO ",30
  66. 640  DATA   "PERHAPS", 28, "SORRY", 31, "WHAT ",25, "WHEN ",25
  67. 650  DATA   "WHY DON'T I", 32, "WHY CAN'T YOU@", 33, "YES", 22
  68. 660  DATA   "YOU@ WANT", 34,  "YOU@ NEED", 34," ARE ",17," I ",27 
  69. 670  DATA  "YOU@ ARE@ SAD", 35, "YOU'RE* SAD", 35
  70. 680  DATA   "YOU@ ARE@ UNHAPPY", 35, "YOU'RE* UNHAPPY", 35
  71. 690  DATA  "YOU@ ARE@ DEPRESSED", 35, "YOU'RE* DEPRESSED", 35
  72. 700  DATA    "YOU@ ARE@ SICK", 35, "YOU'RE* SICK", 35
  73. 710  DATA  "YOU@ ARE@ HAPPY", 36, "YOU'RE* HAPPY", 36
  74. 720  DATA   "YOU@ ARE@ ELATED", 36, "YOU'RE* ELATED", 36
  75. 730  DATA   "YOU@ ARE@ GLAD", 36, "YOU'RE* GLAD", 36
  76. 740  DATA   "YOU@ ARE@ BETTER,", 36, "YOU'RE* BETTER", 36
  77. 750  DATA  "YOU@ FEEL YOU@", 37, "YOU@ THINK YOU@", 37
  78. 760  DATA  "YOU@ BELIEVE YOU@", 37, "YOU@ WISH YOU@", 37
  79. 770  DATA  " YOU@ ARE@", 38, "YOU'RE*", 38, "YOU@ CAN'T", 39 
  80. 780  DATA   "YOU@ CANNOT", 39, "YOU@ DON'T", 40,  "YOU@ FEEL", 41
  81. 790  REM  KEYWORDS.NONE FOUND
  82. 800  IF YO$ = ""  THEN 810
  83. 805 RAN =  INT( RND(1) *5) +1: ON RAN GOTO 810,810,810,860,860
  84. 810 RAN =  INT( RND(1) *4) +1: ON RAN GOTO 820,830,840,850
  85. 820  PRINT "I AM NOT SURE I UNDERSTAND YOU FULLY.":X = 1: GOTO 900
  86. 830  PRINT "PLEASE GO ON.":X = 1: GOTO 900
  87. 840  PRINT "WHAT DOES THAT SUGGEST TO YOU?":X = 1: GOTO 900
  88. 850  PRINT "DO YOU FEEL STRONGLY ABOUT DISCUSSING SUCH THINGS?":X = 1: GOTO 900
  89. 860 RAN =  INT( RND(1) *3) +1: ON RAN GOTO 870,880,890
  90. 870  PRINT "LET'S DISCUSS FURTHER WHY YOUR" +YO$ +".":X = 1: GOTO 900
  91. 880  PRINT "EARLIER YOU SAID YOUR" +YO$ +".":X = 1: GOTO 900
  92. 890  PRINT "DOES THAT HAVE ANYTHING TO DO WITH THE FACT THAT YOUR" +YO$ +"?":X = 1: GOTO 900
  93. 900  RETURN 
  94. 910  REM  MARKER REMOVER
  95. 920  IF X = 1  THEN 960
  96. 930  FOR PS = 1 TO  LEN(DR$)
  97. 940  IF  MID$ (DR$,PS,1) = "@"  OR  MID$ (DR$,PS,1) = "*"  THEN DR$ =  LEFT$(DR$,PS -1) + MID$ (DR$,PS +1)
  98. 950  NEXT PS
  99. 960  RETURN 
  100. 970  REM  REPLY
  101. 980  REM  REPLY.WHERE TO JUMP
  102. 990  IF K = 1  THEN 1470
  103. 1000  ON JU GOTO 1020,1030,1040,1050,1060,1070,1080,1090,1100,1110,1120,1130,1140,1150,1160,1170,1180,1190,1200,1210,1220,1230,1240,1250,1260,1270,1280,1290,1300,1310,1320,1370,1380,1390,1400,1410,1420,1430,1440,1450,1460
  104. 1010  REM  REPLY.REPLIES
  105. 1020  PRINT "DO COMPUTERS WORRY YOU?": GOTO 1470
  106. 1030  PRINT "I AM NOT INTERESTED IN NAMES.": GOTO 1470
  107. 1040  PRINT "IN WHAT WAY?": GOTO 1470
  108. 1050  PRINT "DO YOU OFTEN THINK OF" +DR$ +"?": GOTO 1470
  109. 1060  PRINT "DID YOU THINK I WOULD FORGET" +DR$ +"?": GOTO 1470
  110. 1070  PRINT "REALLY, " +DR$ +"?": GOTO 1470
  111. 1080  PRINT "WHAT DOES THAT DREAM SUGGEST TO YOU?": GOTO 1470
  112. 1090  PRINT "DO YOU THINK IT'S LIKELY THAT IF " +DR$ +"?": GOTO 1470
  113. 1100  PRINT "REALLY," +KE$ +"?": GOTO 1470
  114. 1110  PRINT "WHAT IF YOU WERE" +DR$ +"?": GOTO 1470
  115. 1120  PRINT "WERE YOU REALLY?": GOTO 1470
  116. 1130  PRINT "WOULD YOU LIKE TO BELIEVE I WAS" +DR$ +"?": GOTO 1470
  117. 1140  PRINT "TELL ME MORE ABOUT YOUR FAMILY.": GOTO 1470
  118. 1150  PRINT "YOUR" +DR$ +".": GOSUB 1480: GOTO 1470
  119. 1160  PRINT "CAN YOU THINK OF A SPECIFIC EXAMPLE?": GOTO 1470
  120. 1170  PRINT "WHY ARE YOU INTERESTED IN WHETHER I AM" +DR$ +" OR NOT?": GOTO 1470
  121. 1180  PRINT "DID YOU THINK THEY MIGHT NOT BE " +DR$ +"?": GOTO 1470
  122. 1190  PRINT "DO YOU BELIEVE YOU ARE" +DR$ +"?": GOTO 1470
  123. 1200  PRINT "IS THAT THE REAL REASON?": GOTO 1470
  124. 1210  PRINT "YOU BELIEVE I CAN" +DR$ +", DON'T YOU?": GOTO 1470
  125. 1220  PRINT "WHETHER OR NOT YOU CAN" +DR$ +" DEPENDS ON YOU MORE THAN ON ME.": GOTO 1470
  126. 1230  PRINT "YOU SEEM QUITE POSITIVE.": GOTO 1470
  127. 1240  PRINT "I AM SORRY, I SPEAK ONLY ENGLISH.": GOTO 1470
  128. 1250  PRINT "HOW DO YOU DO.": GOTO 1470
  129. 1260  PRINT "WHY DO YOU ASK?": GOTO 1470
  130. 1270  PRINT "WHAT MAKES YOU THINK I AM" +DR$ +"?": GOTO 1470
  131. 1280  PRINT "WE WERE DISCUSSING YOU, NOT ME.": GOTO 1470
  132. 1290  PRINT "YOU DON'T SEEM QUITE CERTAIN.": GOTO 1470
  133. 1300  PRINT "WHY ARE YOU CONCERNED OVER MY " +DR$ +"?": GOTO 1470
  134. 1310  PRINT "ARE YOU SAYING 'NO' JUST TO BE NEGATIVE?": GOTO 1470
  135. 1320 RAN =  INT( RND(1) *4) +1: ON RAN GOTO 1330,1340,1350,1360
  136. 1330  PRINT "PLEASE DON'T APOLOGIZE.": GOTO 1470
  137. 1340  PRINT "APOLOGIES ARE NOT NECESSARY.": GOTO 1470
  138. 1350  PRINT "WHAT FEELINGS DO YOU HAVE WHEN YOU APOLOGIZE?": GOTO 1470
  139. 1360  PRINT "YOU NEEDN'T FEEL THAT YOU HAVE TO APOLOGIZE.": GOTO 1470
  140. 1370  PRINT "DO YOU BELIEVE I DON'T" +DR$ +"?": GOTO 1470
  141. 1380  PRINT "DO YOU THINK YOU SHOULD BE ABLE TO" +DR$ +"?": GOTO 1470
  142. 1390  PRINT "WHAT WOULD IT MEAN TO YOU IF YOU GOT" +DR$ +"?": GOTO 1470
  143. 1400  GOSUB 1510: GOSUB 1540: PRINT "I AM SORRY TO HEAR YOU ARE" +DR$ +".": GOTO 1470
  144. 1410  GOSUB 1510: GOSUB 1540: PRINT "HOW HAVE I HELPED YOU TO BE" +DR$ +"?": GOTO 1470
  145. 1420  PRINT "DO YOU REALLY THINK SO?": GOTO 1470
  146. 1430  PRINT "IS IT BECAUSE YOU ARE" +DR$ +"THAT YOU CAME TO ME?": GOTO 1470
  147. 1440  PRINT "HOW DO YOU KNOW YOU CAN'T" +DR$ +"?": GOTO 1470
  148. 1450  PRINT "DON'T YOU REALLY" +DR$ +"?": GOTO 1470
  149. 1460  PRINT "TELL ME MORE ABOUT SUCH FEELINGS.": GOTO 1470
  150. 1470  RETURN 
  151. 1480  REM  KEYWORD IS MY
  152. 1490  IF  LEN(DR$) >11  THEN YO$ = DR$
  153. 1500  RETURN 
  154. 1510  REM  REMOVE @
  155. 1520  IF  MID$ (KE$,4,1) = "@"  THEN DR$ =  RIGHT$(KE$, LEN(KE$) -9)
  156. 1530  RETURN 
  157. 1540  REM  REMOVE *
  158. 1550  IF  MID$ (KE$,7,1) = "*"  THEN DR$ =  RIGHT$(KE$, LEN(KE$) -7)
  159. 1560  RETURN